program nome (input,output);

type rect	= record
		     ok			  : boolean;
		     punto		  : integer;
		     xmin,ymin ,xmax,ymax : integer;
		  end;			  
	  point	= record
		     ok	 : boolean;
		     x,y : integer;
		  end;	 

var heap,slides,ultimo : integer;
   slide	       : array[1..50] of rect;
   nums		       : array[1..50] of point;
   tuttobene	       : boolean;

procedure Leggi;
var i : integer;
begin
   for i:=1 to slides do with slide[i] do
   begin
      ok:=false;
      readln(xmin,xmax,ymin,ymax);
   end;
   for i:=1 to slides do with nums[i] do
   begin
      ok:=false;
      readln(x,y);
   end;
end; { Leggi }

function contenuto(a,n : integer ):boolean;
begin
   contenuto:=false;
   if (
       (nums[a].x<slide[n].xmax) and
       (nums[a].x>slide[n].xmin) and
       (nums[a].y>slide[n].ymin) and
       (nums[a].y<slide[n].ymax)
      ) then
   begin
      ultimo:=n;
      contenuto:=true;
   end;
end;

function howmany(n :integer ):integer;
var i,quanti : integer;
begin
   quanti:=0;
   for i:=1 to slides do
      if (not slide[i].ok) then
	 if contenuto(n,i) then
	    quanti:=quanti+1;
   howmany:=quanti;
end;

procedure Elabora;
var esci  : boolean;
   i,chiusi : integer;
begin
   chiusi:=0;
   repeat
      esci:=true;
      for i:=1 to slides do
	 if not (nums[i].ok) then
	 begin
	    if howmany(i)=1 then
	    begin
	       chiusi:=chiusi+1;
	       if chiusi=slides then
		  tuttobene:=true;
	       nums[i].ok:=true;
	       slide[ultimo].ok:=true;
	       slide[ultimo].punto:=i;
	       esci:=false;
	    end
	 end;
   until esci;
end;

procedure Scrivi;
var i : integer;
begin
   writeln('Heap ',heap:1);
   if tuttobene then
   begin
      for i:=1 to slides do
	 write('(',chr(i+ord('A')-1),',',slide[i].punto:1,')',' ' );
      writeln;
   end
   else
      writeln('none');
   writeln;
end;

begin
   reset (input,'slides.in');

   heap:=0;
   read(slides);
   while (slides<>0) do
   begin
      tuttobene:=false;
      heap:=heap+1;
      readln;
      Leggi;
      Elabora;
      Scrivi;
      read(slides);
   end;

   close(input);
end.